Программирование. Рекурсия Pascal-Паскаль

Рекурсия Pascal-Паскаль

Подпрограммы в Паскале могут обращаться сами к себе. Такое обращение называется рекурсией.

Для того чтобы такое обращение не было бесконечным, в тексте подпрограммы должно быть условие, по достижению которого дальнейшее обращение к подпрограмме не происходит.

Пример.

Рассмотрим математическую головоломку из книги Ж. Арсака «Программирование игр и головоломок».

Построим последовательность чисел следующим образом: возьмем целое число i>1. Следующий член последовательности равен i/2, если i четное, и 3 i+1, если i нечетное. Если i=1, то последовательность останавливается.

Математически конечность последовательности независимо от начального i не доказана, но на практике последовательность останавливается всегда.

Применение рекурсии позволило решить задачу без использования циклов, как в основной программе, так и в процедуре.

Пример программы с использованием рекурсии
Program Arsac;
Var first: word;
Procedure posledov (i: word);
Begin
   Writeln (i);
   If i=1 then exit;
   If odd(i) then posledov(3*i+1) else posledov(i div 2);
End;
Begin
   Write (' введите первое значение '); readln (first);
   Posledov (first);
   Readln ;
End.

Программист разрабатывает программу, сводя исходную задачу к более простым. Среди этих задач может оказаться и первоначальная, но в упрощенной форме. Например, для вычисления F( N) может понадобиться вычислить F( N-1). Иными словами, частью алгоритма вычисления функции будет вычисление этой же функции.

Алгоритм, который является своей собственной частью, называется рекурсивным. Часто в основе такого алгоритма лежит рекурсивное определение.

Пример рекурсивного алгоритма
N! = ( N-1)!* N, если N=0, то N!= 1

Любое рекурсивное определение состоит из двух частей. Одна часть определяет понятие через него же, другая часть – через иные понятия.

Пример рекурсивного алгоритма
2n= 2 n-1*2, если n=0, то 2 n= 1

Процедура является рекурсивной, если она обращается сама к себе прямо или косвенно (через другие процедуры).

схема рекурсии

Заметим, что при косвенном обращении все процедуры в цепочке – рекурсивные.

Все сказанное о процедурах целиком относится и к функциям.

Пример рекурсивной функции вычисления факториала
Function factorial(N: integer) : longint;
Begin
   If N= 0 then
   Factorial := 1
   Else Factorial := factorial(N-1) * N
End;

Рекурсия изнутри

Это может показаться удивительным, но самовызов процедуры ничем не отличается от вызова другой процедуры. Что происходит, если одна процедура вызывает другую? В общих чертах следующее:

  • в памяти размещаются параметры, передаваемые процедуре (но не параметры-переменные!);
  • в другом месте памяти сохраняются значения внутренних переменных вызывающей процедуры;
  • запоминается адрес возврата в вызывающую процедуру;
  • управление передается вызванной процедуре.

Если процедуру вызвать повторно из другой процедуры или из нее самой, будет выполняться тот же код, но работать он будет с другими значениями параметров и внутренних переменных. Это и дает возможность рекурсии.

Пусть рекурсивная процедура Power( X, N, Y) возводит число X в степень N и возвращает результат Y .

Пример рекурсивной процедуры, возводящей число в степень
Procedure Power (X: real; N: integer; var Y: real);
Begin
   If N=0 then
      Y:= 1
   Else Begin Power(X, N-1,Y);
      Y:= Y*X;
   End ;
End ;

Проследим за состоянием памяти в процессе выполнения вызова данной процедуры Power(5,3, Y). Стрелка «->» означает вход в процедуру, стрелка «<-» означает выход из нее.

состояние памяти при рекурсии

Число копий переменных, одновременно находящихся в памяти, называется глубиной рекурсии. Как видно из примера, сначала она растет, а затем сокращается.

Подведем итог.

  • рекурсивной называется такая процедура или функция, которая вызывает сама себя;
  • для завершения процесса рекурсии в алгоритме рекурсивной функции (процедуры) обязательно должно быть условие, обеспечивающее непосредственное завершение функции (процедуры).

Напишем программу вычисления функции, заданной следующим образом:

F(1)=1; F(2n)=F(n); F(2n+1)=F(n)+F(n+1)

Решение: из определения видно, что вычисление функции от аргумента, сводится к вычислению этой же функции от меньшего аргумента, и процесс уменьшения аргумента продолжается до тех пор, пока в качестве аргумента не получится единица. Значение функции от единицы определено.

Таким образом, работа алгоритма будет состоять из некоторого количества шагов, на каждом из которых будут выполняться два действия:

  • Определение четности или нечетности аргумента. От этого зависит выбор формулы вычислений;
  • Выполнение вычислений. Фактически это будет сводиться к определению нового аргумента функции.
Пример рекурсивной программы вычисления функции
Program primer;
Uses crt;
Var
   N, a: integer;
Function f(n:integer):integer;
Begin
   If n =1 then
      f :=1 {условие завершения рекурсии}
   Else
   Begin
      If odd ( n ){проверка на нечетность числа}
      then begin
         n:= n div 2;
         f:=f(n)+f(n+1)
      end
      else begin
         n:= n div 2;
         f:=f(n)
      end;
   end ;
end ;
begin {начало основной программы}
   clrscr;
   write(' Введите число – ');
   readln(n);
   a:=f(n);
   write(' результат – ', a);
end.

Рекурсивная программа построения снежинки

Написать программу, строящую на экране изображение:

Пример рекурсивной программы построения окружностей

Изображение строится по следующему правилу: строится окружность с заданным радиусом r. Затем на диаметрально противоположных точках окружности ( x- r и x+ r)строится вновь окружность меньшего радиуса ( r=3 r/5). Для каждой меньшей окружности на диаметрально противоположных точках вновь строится окружность меньшего радиуса, и т.д., пока радиус не уменьшится до 10.

Пример рекурсивной программы построения окружностей
program recurs;
uses graph;
var x,y,r,d,m:integer;
procedure ris(x,y,r:integer);
var i:integer;
begin
   if r<10 then exit;
   circle(x,y,r);
   for i:=1 to 1000 do; { просто цикл задержки }
   ris(x+r,y,r*3 div 5);
   ris(x-r,y,r*3 div 5);
end ;
begin {начало основной программы}
   d:=detect;
   initgraph(d,m,'e:\bp\bgi');
   x:=320;
   y:=240;
   r:=120;
   ris(x,y,r);
   readln ;
end.

Пример рекурсивной программы построения снежинки

Как видно из рисунка, здесь опять повторяются одни и те же фрагменты. Построение выполняется так: на окружности заданного радиуса r берется 6 равноотстоящих точек (начиная от угла в 0 0, с шагом ?/3), из каждой точки к центру окружности проводятся радиусы. Затем каждая из этих точек выступает центром новой, меньшей окружности с радиусом r=2 r/5. На каждой меньшей окружности вновь берется 6 равноотстоящих точек, из которых строятся радиусы к центру, и т.д., пока радиус не станет меньше или равен 1.

Пример рекурсивной программы построения снежинки
program sneg;
uses graph, crt;
var
   x,y,r,d,m:integer;
procedure ris(x,y,r:integer);
var
   x1,y1,t:integer;
begin
   if r<=1 then begin putpixel(x,y,15);exit end;
   for t:=0 to 6 do
   begin
      x1:=x+trunc(r*cos(t*pi/3));
      y1:=y+trunc(r*sin(t*pi/3));
      line(x,y,x1,y1);
      ris(x1,y1,r*2 div 5);
      delay(500);
   end;
end;
begin
   d:=detect;
   initgraph(d,m,'e:\bp\bgi');
   x:=320;
   y:=240;
   r:=80;
   ris(x,y,r);
   readln;
end.

Пример «Кривой Дракона».

Рассмотрим пример решения еще одной классической задачи: «Кривая Дракона».

Изображение кривой Дракона выглядит так:

Пример рекурсивной программы «Кривая Дракона»

Очень красиво, не правда ли. Разберемся, как же эта кривая получается.

Возьмем длинную полоску бумаги и сложим ее пополам, а затем развернем на 90. Если смотреть на полоску сбоку, то получится ломаная линия из двух перпендикулярных участков: см. рис. а. Теперь сложим полоску пополам дважды и также дважды развернем на 90 так, как это показано на рис. б. Получим ломаную линию уже из четырех отрезков, причем угол между смежными отрезками составляет 90. Наконец, если сложение и разворачивание полоски осуществить три раза, то в результате получится фигура, представленная на рис. в. Продолжая этот процесс, можно получить кривую, аналогичную той, которая представлена на рис. 1. Эту причудливую кривую называют кривой дракона. Способ построения подсказывает, что она не имеет самопересечений.

Пример рекурсивной программы «Кривая Дракона»

Кривая дракона впервые была описана в популярной литературе в журнале Scientific American в 1967 году. Заметка о ней появилась в колонке “Математические игры”, которую вел Мартин Гарднер. Первоначально использовалось полное название кривой – «дракон Хартера — Хейтуэя», которое ей дал основатель компьютерной фрактальной геометрии Бенуа Мандельброт, именем которого названо знаменитое множество. В дальнейшем стали говорить просто о кривой дракона. Выше мы описали один из алгоритмов построения кривой. На наш взгляд, он несколько запутан (хотя и достаточно прост в реализации). Приведем описание алгоритма построение кривой, близкое к тому, которое использовалось Мартином Гарднером.

Пример рекурсивной программы «Кривая Дракона»

Рассмотрим горизонтальный отрезок как кривую дракона нулевого порядка. Разделим отрезок пополам и построим на нем прямой угол, как показано на рис. а).

Пример рекурсивной программы «Кривая Дракона»

Получим кривую дракона первого порядка. На сторонах прямого угла снова построим прямые углы (рис. б).

При этом вершина первого угла всегда находится справа, если смотреть из точки A (начала кривой) вдоль первого отрезка кривой, а направления, в которых строятся вершины остальных углов, чередуются. На рис. в) и г) показаны кривые дракона третьего и четвертого порядков соответственно.

Пример рекурсивной программы «Кривая Дракона»

Пример рекурсивной программы «Кривая Дракона»
program dragon;
uses graph;
var k,d,m:integer;
procedure ris(x1,y1,x2,y2,k:integer);
var xn,yn:integer;
begin
   if k>0 then
   begin
      xn:=(x1+x2) div 2 +(y2-y1) div 2;
      yn:=(y1+y2) div 2 -(x2-x1) div 2;
      ris(x1,y1,xn,yn,k-1);
      ris(x2,y2,xn,yn,k-1);
   end
   else begin line(x1,y1,x2,y2); end;
end;
begin
   readln ( k );{задаем порядок кривой}
   d:=detect;
   initgraph(d,m,'e:\bp\bgi');
   ris(200,300,500,300,k);
   readln;
end.